@echo off
REM Sample batch file for a Fluent 6.3.26 serial job
@echo on

REM --- Call setup file for Fluent
call setup_fluent.bat

REM --- Set FLUENT_VERSION, ROOTDIR, IN_FILE, and OUT_FILE_1 variables.
REM --- (If more than one output file, create variables OUT_FILE_2, etc.)
set FLUENT_VERSION=2d
set ROOTDIR=\\tc.cornell.edu\tc\Users\%USERNAME%
set IN_FILE=inputfile
set OUT_FILE_1=outputfile
REM ---> uncomment if needed ---> set OUT_FILE_2=datafile.dat

REM --- Create, or delete and re-create, a clean user directory on T:
if exist T:\%USERNAME% del /S /Q T:\%USERNAME%
if exist T:\%USERNAME%\NUL rmdir /S /Q T:\%USERNAME%
mkdir T:\%USERNAME%
cd /D T:\%USERNAME%

REM --- Copy the input files from ROOTDIR. 
copy %ROOTDIR%\* T:\%USERNAME%\

REM --- Fluent will stall with no output if %OUT_FILE_n% is present.
del /Q T:\%USERNAME%\%OUT_FILE_1%
REM ---> uncomment if needed ---> del /Q T:\%USERNAME%\%OUT_FILE_2%

REM --- Execute Fluent; best to specify full path name for input script file
REM --- NOTE: script is assumed to contain output filename(s) without path
fluent %FLUENT_VERSION% -g -i T:\%USERNAME%\%IN_FILE%

REM --- Check to see if Fluent is finished
:loops
call sleep 30
pslist.exe | find "%PULIST_NAME%" && goto loops

REM --- Copy the output file(s) back to ROOTDIR.
REM --- (Add extra copy commands if there is more than a single output file.)
REM --- Overwrite any pre-existing output file(s)
copy /Y T:\%USERNAME%\%OUT_FILE_1% %ROOTDIR%\
REM ---> uncomment if needed ---> copy /Y T:\%USERNAME%\%OUT_FILE_2% %ROOTDIR%\

REM --- Clean up files from this job
cd /D T:\
rmdir /S /Q T:\%USERNAME%

REM --- End the job
vsched -c